#declare RADIUS = 2;
#declare TORUS =
 difference {
  torus { 1,RADIUS         }
  torus { 1,RADIUS - 0.001 }
  rotate <0,45,0>
 }
#declare SECTION =
 union {
  difference {
   cylinder { <0,0,4> <0,0,6> RADIUS + 0.01 }
   cylinder { <0,0,3> <0,0,7> RADIUS - 0.01 }
   finish { ambient 0 }
  }
  cylinder { <0,0,4> <0,0,5> RADIUS }
 }

union {
 object { SECTION translate < 1,0,0> }
 object { SECTION translate <-1,0,0> }
 pigment { rgb <1,1.3,1> }
 no_shadow
 translate <1.2,-2.6,0>
}
union {
 intersection {
  object { SECTION translate < 1,0,0> }
  object { SECTION translate <-1,0,0.1> }
  pigment { rgb <1.3,1.2,0.5> }
 }
 no_shadow
 translate <-3.2,-2.6,0>
}
object {
 TORUS
 texture {
  uv_mapping
  pigment { checker rgb <0.8,1,0.8>, rgb <0.7,0.9,0.7> scale 0.08333 }
 }
 rotate <30,0,0> translate <1.2,2.1,0>
}
intersection {
 object { TORUS }
 cylinder { <0,sqrt(3),0> <0,-sqrt(3),0> 1 }
 texture {
  uv_mapping
  pigment { checker rgb <1,0.9,0>, rgb <0.9,0.8,0> scale 0.08333 }
 }
 rotate <30,0,0> translate <-3.2,2.1,0>
}

background   { color rgbt <1,1,1,0> }
light_source { < 0  ,-2,1> color 0.5 parallel }
light_source { < 0  , 4,9> color 1   parallel
 area_light <4,0,0>, <0,0,4>, 9, 9 adaptive 1 jitter }
light_source { <-3.2, 8,4> color 0.7
 area_light <2,0,0>, <0,0,2>, 9, 9 adaptive 1 jitter }
camera {
 orthographic
 right    x * image_width / image_height
 location <0,0,8>
 look_at  <0,0,0>
 sky      <0,1,0>
 angle    61
}