File:Hoberman sphere.gif
Jump to navigation
Jump to search
Size of this preview: 512 × 512 pixels. Other resolution: 240 × 240 pixels.
Original file (512 × 512 pixels, file size: 768 KB, MIME type: image/gif, looped, 40 frames, 4.0 s)
Summary
| Description | Animation of a Hoberman sphere in the form of a spherical icosidodecahedron with one scissor per icosidodecahedron edge. Each of its six geodesics is distinctly coloured, the grey ring viewed face on, and the far hemisphere is muted. Adjacent geodesics are at arctan(2) ≈ 63.435° from each other. |
| Source | Own work |
| Author | Cmglee |
POV-Ray source code
| Hoberman_sphere.pov | Hoberman_sphere.ini |
#declare DISPLACEMENT = 0.5 - 0.5 * cos(radians(clock));
// #declare DISPLACEMENT = 0.5 - 0.5 * cos(radians(180));
#declare HUB = cylinder { <0,1.02,0>, <0,0.96,0>, 0.05 }
#declare LEFT =
prism {
cubic_spline -0.01, 0.5, 6,
<-6,2> <6,2> <0,-0.6> /// middle coord on this line must match...
<-6,2> <6,2> <0,-0.6> /// middle coord on this line
scale 0.048
rotate <90,0,-5 - 65 * DISPLACEMENT>
translate <0,1 - 0.53 * DISPLACEMENT,0>
}
#declare RIGHT =
union {
object { LEFT scale <-0.999,0.999,-0.9> }
object { LEFT scale <-1,1,-1> pigment { rgbt <0,0,0,0.75> } }
}
#declare SCISSOR =
union {
object { LEFT }
object { RIGHT }
cylinder { <0,1,0.025>, <0,1,-0.025>, 0.02 pigment { rgbt <0,0,0,0.75> }
translate <0,-0.54 * DISPLACEMENT,0> }
object { HUB pigment { rgb 0.0 } translate <0, - 0.25 * DISPLACEMENT,0> rotate <0,0,18> }
object { HUB pigment { rgb 0.3 } translate <0,-0.07 - 0.77 * DISPLACEMENT,0> rotate <0,0,18> }
no_shadow
}
#declare HALF =
union {
object { SCISSOR }
object { SCISSOR rotate <0,0,36> }
object { SCISSOR rotate <0,0,72> }
object { SCISSOR rotate <0,0,108> }
object { SCISSOR rotate <0,0,144> }
}
#declare RING =
union {
object { HALF }
object { HALF rotate <0,0,180> }
}
#declare OBLIQUE = object { RING rotate <degrees(atan(-2)),0,0> }
object { OBLIQUE rotate <0,0, 0> pigment { rgb <0.8,0.5,1.0> } }
object { OBLIQUE rotate <0,0, 72> pigment { rgb <1.0,0.3,0.3> } }
object { OBLIQUE rotate <0,0,144> pigment { rgb <0.8,0.8,0.0> } }
object { OBLIQUE rotate <0,0,216> pigment { rgb <0.0,0.8,0.5> } }
object { OBLIQUE rotate <0,0,288> pigment { rgb <0.3,0.5,1.0> } }
object { RING pigment { rgb 0.7 } }
plane { <0,0,1>, 0.02 pigment { rgbt <2,2,2,0.7> } }
background { rgbt <1,1,1,0> }
global_settings { ambient_light 8 }
light_source { <0,1,1> color 0.5 parallel
area_light <5,0,0>, <0,0,5>, 5, 5 adaptive 1 jitter }
camera {
orthographic
right x * image_width / image_height
sky <0,1,0>
location <0,0,5.5>
look_at <0,0,0>
angle 21.5
}
|
Antialias=On
Antialias_Threshold=0.1
Antialias_Depth=2
Input_File_Name="hoberman_sphere.pov"
Initial_Frame=0
Initial_Clock=0.0
Final_Frame=39
Final_Clock=360.0
Cyclic_Animation=on
Pause_when_Done=off
|
Licensing
I, the copyright holder of this work, hereby publish it under the following licenses:
This file is licensed under the Creative Commons Attribution-Share Alike 4.0 International license.
- You are free:
- to share – to copy, distribute and transmit the work
- to remix – to adapt the work
- Under the following conditions:
- attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use.
- share alike – If you remix, transform, or build upon the material, you must distribute your contributions under the same or compatible license as the original.
|
Permission is granted to copy, distribute and/or modify this document under the terms of the GNU Free Documentation License, Version 1.2 or any later version published by the Free Software Foundation; with no Invariant Sections, no Front-Cover Texts, and no Back-Cover Texts. A copy of the license is included in the section entitled GNU Free Documentation License. |
You may select the license of your choice.
File history
Click on a date/time to view the file as it appeared at that time.
| Date/Time | Thumbnail | Dimensions | User | Comment | |
|---|---|---|---|---|---|
| current | 10:58, 31 March 2026 | | 512 × 512 (768 KB) | wikimediacommons>Cmglee | Optimise using ezgif.com with compression level 95, eliminate local color tables and reduce to 61 colors |
File usage
There are no pages that use this file.
